返回资讯中心
外部精选
软件工程
#开发者实时流

SakaQL:一种新的通用关系型编程语言发布

来源标题:SakaQL: A new general-purpose relational programming language

开发者推出名为 SakaQL 的通用关系型编程语言,旨在替代 SQL 的糟糕人机工程体验,并称其具备其他语言没有的特性。该语言将驱动开发者数据管理产品 Saka。作者认为 EdgeQL 因要求用户做出不合理的取舍而未能成功,而 Datalog、Cypher、CodeQL 等则通过专注细分场景获得成功。

Hacker News 最新eejdoowad2026/11/19 · 今天30 分钟阅读

以下正文由 AI 翻译自 Hacker News 最新(原文版权归原站所有),可能存在偏差,重要内容请以原文为准。

SakaQL:一种新的通用关系型编程语言

用 SakaQL 渲染的图形

太长不看版:SQL 很糟糕,所以我做了一门通用关系型编程语言。它用起来像现代语言,还有一些别处找不到的特性。它为 Saka 提供动力——那是一个面向开发者、即将推出的数据管理产品。

SQL 是一门有缺陷的语言,人机工效很差。其他语言靠自身优势争取用户,SQL 却不是。它跟数据库捆绑销售,你要是不喜欢,那只能自认倒霉。你甚至没法在它之上构建更好的语言,因为性能要求不可避免地需要 SQL 那种底层控制力。

有人试过。EdgeQL 雄心勃勃、前景可期,但最终没成,因为它要求用户做一个不合理的取舍:得到更好的语言,却要把数据押在一家初创公司未经检验的技术上,失去与更广泛数据生态的兼容性,还要花时间学新东西。对比一下选一个新的 SQL 数据库:试一试,最坏情况也不过是回到 Postgres。

其他关系型语言则是靠守住细分领域才取得成功:Datalog 用于递归查询,Cypher 用于图遍历,CodeQL 用于代码分析。出了自己的细分领域,它们就无关紧要了。

尽管 SQL 在数据库领域占据主导,它在通用编程领域并没有取得显著进展,因为它的人机工效让人无法忍受。声明式 schema 和查询非常有用,但如果它们带着 SQL 的那堆包袱,开发者就会集体拒绝。

那么,如果你去掉这些包袱,叠加从现代编程语言偷来的理念,再撒上一点自家原创的创新,会怎样?

SakaQL 是一门通用关系型编程语言。它以关系代数为根基,采用基于表达式的语法、受 TypeScript 和 EdgeQL 启发的基于集合的类型系统,并对语言设计惯例抱有一种不寻常的怀疑态度。

def fizzbuzz(n! int) =
  1..n
  map i => i -> {
    i modulo 15 == 0 then "FizzBuzz"
    else i modulo 3 == 0 then "Fizz"
    else i modulo 5 == 0 then "Buzz"
    else "\{i}"
  }
proc main(): void = do {
  print(str::join(fizzbuzz(100), "\n"))
}

我希望这能传达我的意图:SakaQL 看起来、用起来都应该像一门现代语言。

效仿前辈身上你欣赏的东西固然很好。但指出他们的错误要有趣得多。

以下是 SakaQL 一些受 SQL 缺陷启发的设计决策:

拿一个常见问题来说:按库存价值计算,每个供应商的前五个产品是什么?在 PostgreSQL 中:

SELECT vendor, name
FROM (
  SELECT
    vendor,
    name,
    ROW_NUMBER() OVER (PARTITION BY vendor ORDER BY price * stock DESC) AS position
  FROM products
) AS ranked
WHERE position <= 5;

在 SakaQL 中:

products
by .vendor
aggv {
  .
  by .price * .stock
  last 5
  map .v.name
}

有些 SQL 方言加入了 QUALIFY 和 LIMIT BY 之类的语法,让这类查询稍微好受一点,但每加一个都是在 SQL 本已臃肿的语法上再堆一层。

更多对比见《SQL 与 SakaQL 对比》。

值

值是带类型的袋(无序多重集)。空袋取代 NULL,袋会隐式展平,所以不存在袋的袋。

// 以下都是 "一个包含整数 7 的袋" 的等价写法
7
{7}
{{7}}
int:7
int:{7}

// 'n 表示某个元素重复 n 次
{"a", "b", "b", "c"} // {"a", "b"'2, "c"}
{false'7, true}

// 空袋必须有上下文类型
int:{}
f64:{}
str:{}
bool:{}

类型

类型是量化的集合,包含两部分:

def a: f64'0 = {} // 一个空的 64 位浮点数袋
def b: bool'1 = true // 一个一元布尔袋
def c: int'{3..7} = {1, 2, 3, 4} // 一个包含 3 到 7 个整数的袋

!、?、* 和 + 分别表示区间 1、{0, 1}、{0..inf} 和 {1..inf}。

def a* int 是 def a: int'* 的语法糖。

def a? f64 = 8.0 // 一个可选的 64 位浮点数袋
def d* i32 = {1, 2} // 一个 n 元的 32 位有符号整数袋
def e+ str = {"a", "b", "c"} // 一个非空字符串袋

记录、元组和映射

记录、元组和映射是复合类型,可以用集合声明来命名。

set Person = (first: str, last: str)
def people: Person'* = {
  (first: "SpongeBob", last: "SquarePants")
  (first: "Patrick", last: "Star")
}

元组把有序的值分组。

set Point = [f64, f64]
def points: Point'* = {[1, 2], [3, 4], [5, 6]}

映射是 (k, v) 记录的语法糖。

// 等价
set int_to_str1 = int -> str
set int_to_str2 = (k: int, v: str)

def x: int_to_str1'* = {1 -> "a", 2 -> "b", 3 -> "c"}

表达式

表达式变换袋。

def a = 1 + 2 // 3
def b = true or false // true

算术表达式是逐点运算的,把第一个袋里的每个值与第二个袋里的每个值配对。

def a = 1 + 2 // 3
def b = {2, 3} * {1, 10} // {2, 3, 20, 30}
def c = "hi \{"mo", "jo"}" // {"hi jo", "hi mo"}

聚合函数是集合式表达式。

sum({1, 2, 3}) // 6
count({"a"'3, "b"'6}) // 9
distinct({1, 1, 1, 2, 2, 3}) // {1, 2, 3}

管道表达式

管道表达式是中缀表达式,用来取代 SQL 的各种子句。

if 和 map 是过滤和投影运算符。. 指代当前管道元素。

def person = {
  (name: "Ann", age: 12)
  (name: "Ann", age: 9)
  (name: "Bo", age: 30)
  (name: "Cy", age: 16)
}
def kid_names =
  person
  if .age < 18
  map .name

或者,用 => 语法给当前管道元素命名。

def kid_names =
  person
  if p => p.age < 18
  map p => p.name

by 创建一个映射,按某个表达式对输入分组。

def is_gt3 = {1, 2, 3, 4, 5} by . > 3
// {
//   false -> 1
//   false -> 2
//   false -> 3
//   true -> 4
//   true -> 5
// }

aggv 变换每个键对应的值集合。

def is_gt3 = {1, 2, 3, 4, 5} by . > 3 aggv sum(.)
// {
//   false -> 6
//   true -> 9
// }

过程式执行

var 声明存储持久化的值。proc 声明描述命令式执行,并允许变异和 I/O 之类的副作用。

var n! f64 = 0
proc add(x! f64): void = do {
  n = n + x
}
proc reset(): void = do {
  n = 0
}

声明式表达式

def 声明描述纯计算:它们没有副作用,并且会编译成关系代数。它们可以引用已存储的值和其他 def 声明。

(原文较长,此处译出前 6000 字,完整内容请点「打开原文」。)

正文由 探How 从来源站点 RSS 同步,内容未经改写;遇到排版缺失或需要图片、视频时请以原文为准。

打开原文
去社区讨论 →